SSWN01 เซนเซอร์วัดความเร็วลม Modern Device Wind Sensor Rev.C MD0550

คำอธิบาย

เซนเซอร์วัดลม วัดความเร็วลมและอุณหภูมิด้วย Sensor วัดความเร็วลมเอาท์พุตแบบอะนาล็อก วัดความเร็วลมแบบความร้อนที่ใช้เทคนิค ในการวัดความเร็วลมที่เรียกว่าเทคนิค “Hot-Wire” Technique.

Specifications

• SKU MD0550
• Modern Device Wind Sensor Rev.C
• Supply Voltage DC 5V
• Supply current 20 – 40 mA (Depending on wind speed)
• Output signal analog 0 – 5V
• Wind Velocities
  • 0 – 60 mph (Miles per hour ,ไมล์ต่อชั่วโมง)
  • 0 – 97 km/h (กิโลเมตรต่อชั่วโมง)

Pinout

1. GND Ground
2. +V แรงดันไฟฟ้า DC5V
3. Out แรงดันไฟขาออก แรงดัน RV คูณด้วย 3 และ ตามการตั้งค่าบนโพเทนชิออมิเตอร์ แรงดันไฟขาออกนี้จะ saturate ( Ground หรือ +V) หากอุณหภูมิโดยรอบเปลี่ยนแปลงไปมากจากอุณหภูมิเมื่อเซ็นเซอร์ถูกปรับเทียบ ความไวของเอาต์พุตนี้สามารถเปลี่ยนแปลงได้โดยการเปลี่ยน R11 ความไวที่สูงขึ้นจะทำให้เซ็นเซอร์อิ่มตัวได้ง่ายขึ้นเมื่ออุณหภูมิโดยรอบเปลี่ยนแปลง
4. RV คือแรงดันลูป Loop ใช้สำหรับสอบเทียบเอาต์พุต RV จะไม่  Saturate และจะไม่ต่ำกว่า  1.8 V
   เอาต์พุตอุณหภูมิ
5. TMP เทอร์มิสเตอร์ตัวแบ่งแรงดันไฟฟ้า โดยจะอ่านค่าได้ประมาณ 2.8 V ที่อุณหภูมิห้อง 25 C เมื่อแรงดันไฟฟ้าลดลงตามอุณหภูมิที่สูงขึ้น และแรงดันไฟฟ้าเพิ่มขึ้นด้วยอุณหภูมิจะต่ำลง

Arduino Sorcce Code

Hardware Setup Wind Sensor < > Arduino

• GND  < > GND
• +V < > 5V
• RV < > A1 // Wind Sensor is powered from a regulated five volt source. WindSpeed_MPH
• TMP < > A0 // TempC thermistor value from sensor

https://github.com/moderndevice/Wind_Sensor

#define analogPinForRV    1   // change to pins you the analog pins are using
#define analogPinForTMP   0

// to calibrate your sensor, put a glass over it, but the sensor should not be
// touching the desktop surface however.
// adjust the zeroWindAdjustment until your sensor reads about zero with the glass over it. 

const float zeroWindAdjustment =  .2; // negative numbers yield smaller wind speeds and vice versa.

int TMP_Therm_ADunits;  //temp termistor value from wind sensor
float RV_Wind_ADunits;    //RV output from wind sensor 
float RV_Wind_Volts;
unsigned long lastMillis;
int TempCtimes100;
float zeroWind_ADunits;
float zeroWind_volts;
float WindSpeed_MPH;

void setup() {
  Serial.begin(57600);   // faster printing to get a bit better throughput on extended info
  // remember to change your serial monitor

  Serial.println("start");
  //   put your setup code here, to run once:
  //   Uncomment the three lines below to reset the analog pins A2 & A3
  //   This is code from the Modern Device temp sensor (not required)
  pinMode(A2, INPUT);        // GND pin      
  pinMode(A3, INPUT);        // VCC pin
  digitalWrite(A3, LOW);     // turn off pullups
}

void loop() {
  if (millis() - lastMillis > 200){      // read every 200 ms - printing slows this down further
    TMP_Therm_ADunits = analogRead(analogPinForTMP);
    RV_Wind_ADunits = analogRead(analogPinForRV);
    RV_Wind_Volts = (RV_Wind_ADunits *  0.0048828125);

    // these are all derived from regressions from raw data as such they depend on a lot of experimental factors
    // such as accuracy of temp sensors, and voltage at the actual wind sensor, (wire losses) which were unaccouted for.

    TempCtimes100 = (0.005 *((float)TMP_Therm_ADunits * (float)TMP_Therm_ADunits)) - (16.862 * (float)TMP_Therm_ADunits) + 9075.4;  
    zeroWind_ADunits = -0.0006*((float)TMP_Therm_ADunits * (float)TMP_Therm_ADunits) + 1.0727 * (float)TMP_Therm_ADunits + 47.172;  //  13.0C  553  482.39
    zeroWind_volts = (zeroWind_ADunits * 0.0048828125) - zeroWindAdjustment;  

    // This from a regression from data in the form of 
    // Vraw = V0 + b * WindSpeed ^ c
    // V0 is zero wind at a particular temperature
    // The constants b and c were determined by some Excel wrangling with the solver.
    
   WindSpeed_MPH =  pow(((RV_Wind_Volts - zeroWind_volts) /.2300) , 2.7265);   
   
    Serial.print("  TMP volts ");
    Serial.print(TMP_Therm_ADunits * 0.0048828125);
    
    Serial.print(" RV volts ");
    Serial.print((float)RV_Wind_Volts);

    Serial.print("\t  TempC*100 ");
    Serial.print(TempCtimes100 );

    Serial.print("   ZeroWind volts ");
    Serial.print(zeroWind_volts);

    Serial.print("   WindSpeed MPH ");
    Serial.println((float)WindSpeed_MPH);
    lastMillis = millis();    
  } 
}

Schematic

• https://cdn.shopify.com/s/files/1/0628/3621/1954/files/WindSensorC4.pdf?v=1664818424

Dimensions

• 17mmx40mm

การติดตั้ง มีรู 2.5mm 2 รู สำหรับยึดสกรู