ป้ายกำกับ: LCD 1602 แบบ i2c

เริ่มต้นด้วยการหา address ของจอ LCD  โดยส่วนมากแล้วจอ LCD แบบ I2C จะใช้ IC PCF8574T เป็น อินเตอร์เฟส  I2C-bus 100 kHz (โหมด I2C บัส มาตรฐาน)

ซึ่งมักจะเป็น Address 0x27  แต่หากเราไม่ทราบ address จริงๆ สามารถใช้ i2c_scanner สแกนขา Address ได้ดัง Code ด้านล่าง

Arduino Playground – I2cScanner

https://playground.arduino.cc/Main/I2cScanner

 // --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// Version 6, November 27, 2015.
//    Added waiting for the Leonardo serial communication.
// 
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  while (!Serial);             // Leonardo: wait for serial monitor
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknown error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}

ตัวอย่างการใช้งาน

 

การต่อใช้งานให้เราต่อ SDA และ  SCL ของ LCD ไปที่ขา A4 และ A5 ของ Arduino UNO โดยขา SDA ต่อ A4  และ SCL ต่อ A5 

จากนั้น ทำการติดตั้ง Library LiquidCrystal_I2C_master และ อัพโหลด Code ตามด้านล่าง

https://github.com/fdebrabander/Arduino-LiquidCrystal-I2C-library

#include <Wire.h> 
#include <LiquidCrystal_I2C.h>


LiquidCrystal_I2C lcd(0x27, 16, 2); // ตั้งค่าที่อยู่ LCD เป็น 0x27 สำหรับการแสดง 16 ตัวอักษรและ 2 บรรทัด

void setup(){
	// initialize the LCD
	lcd.begin();

	// Turn on the blacklight and print a message.
	lcd.backlight();
	lcd.print("http://s2ins.com!"); //พิมพ์ข้อความ
}

void loop()
{
	// Do nothing here...
}